OnUpdate - Form

From Creation Kit
(Redirected from OnUpdate - Alias)
Jump to: navigation, search

Member of: ActiveMagicEffect Script, Alias Script, and Form Script

Event called periodically if the active magic effect/alias/form is registered for update events. This event will not be sent if the game is in menu mode.

Syntax

Event OnUpdate()

Parameters

None

Example

Function SomeFunction()                
	RegisterForUpdate(5.0) ; Before we can use OnUpdate() we must register.
EndFunction
 
Event OnUpdate() ; This event occurs every five seconds		
	If myQuest.GetStage() == 10
		UnregisterForUpdate() ; when we're done with it, make sure to unregister
		Debug.Trace("Got what we needed, so stop polling!")
	EndIf
EndEvent

Notes

  • Aliases and quests will automatically unregister for this event when the quest stops. Active magic effects will automatically unregister when they are removed.
  • This event is not relayed to any aliases or magic effects attached to the form.
  • This event is relayed to other scripts attached to the same object. eg. On a quest form with 2 main quest scripts and a fragment script, an update event registered by one will be received by all three.
  • Be careful with the use of this event. Because it uses real-time, it can start piling up on itself if the OnUpdate doesn't finish before the time is up. To avoid this, try using a longer time at registration, or do a 'single update chain' which looks like the following:
Function StartChain()
  RegisterForSingleUpdate(1.0) ; Give us a single update in one second
EndFunction
 
Event OnUpdate()
	Bool bKeepUpdating = True
	; Do stuff here, and update the bKeepUpdating variable depending on whether you want another update or not
	If bKeepUpdating
		RegisterForSingleUpdate(1.0)
	EndIf
EndEvent

This prevents multiple update events from stacking up on top of each other and slowing Papyrus down. If multiple update events do stack up on top of one another, this will also increase save file size. If enough instances of the event are stacked up in this way, it can cause significant increases in the size of any save file created.

See Also